Anleitung
So geht’s
Vom Generator ins Spiel in wenigen Minuten. Effekte aus der neuronalen Engine kommen farbig und mit Transparenz; Effekte aus der Basis-Engine kommen in 2 Kanälen, die Farbe kommt über den Shader.
- Godot 4
- Das 2-Kanal-Spritesheet, die
.tscn-Szene mit fertigem AnimatedSprite2D, der Farbshader und ein kurzes Skript, das den Effekt richtig abspielt. - Farbiges Spritesheet
- PNG mit den 16 Frames in einem 4 × 4-Raster, schon in der Farbe und dem Stil, die du gewählt hast. Funktioniert in jeder Engine.
- 2-Kanal-Spritesheet
- Das Original: Licht im Rot, Tinte im Grün. Damit wechselt die Farbe im Spiel. Die Farbrampe wird mitgeliefert und erklärt.
- Aseprite und JSON
- Farbiges Spritesheet mit dem JSON für Frames und Tags, im Format, das Phaser, GameMaker, Defold und Aseprite selbst lesen.
- Einzelne Frames
- 16 einzelne PNGs, für alle, die die Animation von Hand zusammenbauen.
- GIF
- Um den Effekt in einem Post, einem Devlog oder auf Discord zu zeigen.
- Neuronale Engine
- Effekte aus der neuronalen Engine kommen schon farbig und mit Transparenz: 32 Frames in einem 8 × 4-Raster, mit 28 Frames pro Sekunde. In Godot spielt die Szene das Spritesheet so ab, wie es ist, ohne den Farbshader; zum Aufhellen oder Abdunkeln nimm
modulate.
- Zieh den Ordner des Effekts ins Projekt, zum Beispiel nach
res://effekte/siegel/. - Instanziiere die Szene
selo.tscndort, wo der Effekt passiert. Sie läuft von selbst. - Ändere die Farbe, wann du willst, auch mitten im Spiel:
# erzeugt den Effekt an der Trefferstelle und färbt ihn rot
var efeito = preload("res://efeitos/corte/corte.tscn").instantiate()
efeito.position = alvo.global_position
efeito.material.set_shader_parameter("tinta", Color("#F0524F"))
add_child(efeito)Wie er abgespielt wird, ist durch den Typ des Effekts schon geregelt:
- Einmalig läuft einmal ab, und der Node löscht sich am Ende selbst. Zum Wiederverwenden schalte
sumir_no_fimim Inspektor aus und rufplay()auf. - Loop läuft ohne Pause. Zum Ausblenden animiere
modulate.aauf 0. - Erscheint und bleibt zeichnet sich (Animation
entra) und bleibt dann an, hin und her (Animationfica).
Jede Instanz hat ihr eigenes Material, also können zehn Kopien derselben Szene zehn Farben haben. Importiere das Spritesheet, wie es ist (Lossless, der 2D-Standard), und nutze keine VRAM-Kompression dafür: Sie verwischt die beiden Kanäle.
In Unity kommt das farbige Spritesheet als normales Spritesheet hinein: Sprite Mode Multiple, nach dem Raster des Sheets geschnitten (8 × 4 bei der neuronalen Engine). Um den Effekt im Spiel zu tönen oder aufzuhellen, nutz die Farbe des SpriteRenderer:
efeito.GetComponent<SpriteRenderer>().color = new Color32(240, 82, 79, 255);Zum Abspielen bau die Animation mit den Frames in Reihenfolge, in der Geschwindigkeit des Effekts (28 Frames pro Sekunde bei der neuronalen Engine).
Phaser, GameMaker, Defold, LÖVE, RPG Maker, Construct: Lade das farbige Spritesheet mit dem Aseprite-JSON herunter. Die Tags sagen schon, wie es abgespielt wird (golpe, laco, oder entra und fica als Ping-Pong). Um die Farbe im Spiel zu ändern, nimm das 2-Kanal-Spritesheet und die Farbrampe unten im Shader deiner Engine.
Es ist dieselbe Rechnung wie im Browser und im Godot-Paket. Licht und Tinte gehen von 0 bis 1; tinta ist die gewählte Farbe.
shader_type canvas_item;
// Haljoy Studio: a folha guarda a luz no vermelho e a tinta no verde.
// Esta rampa pinta as duas na cor escolhida; troque "tinta" a qualquer hora, ate no meio da partida.
uniform vec4 tinta : source_color = vec4(0.91, 0.76, 0.42, 1.0);
uniform int estilo : hint_range(0, 2) = 0; // 0 pintado, 1 cel, 2 pixel
uniform float pixels_por_quadro = 64.0; // so no estilo pixel
uniform vec2 grade = vec2(4.0, 4.0); // colunas e linhas da folha
uniform float halo : hint_range(0.0, 1.0) = 0.0; // o brilho: a luz forte vaza no ar em volta (0 desliga; o site usa 0.85). Le o canal azul da folha
uniform float fumaca : hint_range(0.0, 1.0) = 0.0; // a fumaca neutra: a luz baixa perde a cor, a cor cheia fica so no aceso (o site usa 0.6)
void fragment() {
vec2 uv = UV;
if (estilo == 2) {
vec2 n = grade * pixels_por_quadro;
uv = (floor(uv * n) + 0.5) / n;
}
vec2 t = texture(TEXTURE, uv).rg;
float luz = t.r;
float tin = t.g;
if (estilo > 0) {
luz = luz < 0.16 ? 0.0 : (luz < 0.5 ? 0.42 : (luz < 0.84 ? 0.78 : 1.0));
tin = step(0.42, tin);
}
vec3 cor = tinta.rgb;
vec3 borda = cor * 0.38;
vec3 corpo = mix(borda, cor, smoothstep(0.12, 0.55, luz));
vec3 col = mix(corpo, vec3(1.0, 0.985, 0.95), smoothstep(0.78, 0.95, luz));
if (fumaca > 0.0) {
col = mix(col, dot(col, vec3(1.0 / 3.0)) * vec3(1.06, 1.0, 0.9), fumaca * (1.0 - clamp((luz - 0.62) / 0.14, 0.0, 1.0)));
}
float aL = clamp(luz * 1.6, 0.0, 1.0);
float aT = smoothstep(0.05, 0.4, tin);
vec3 tc = vec3(0.035, 0.04, 0.06) + cor * 0.035;
float a = aL + aT * (1.0 - aL);
vec3 pre = col * aL + tc * aT * (1.0 - aL);
if (halo > 0.0) {
// o brilho vem pronto no canal azul da folha (dois desfoques, feitos na exportacao): 1 leitura por pixel, sem pontilhado
vec2 cel = floor(uv * grade);
vec2 local = fract(uv * grade);
float h = texture(TEXTURE, (cel + clamp(local, vec2(0.004), vec2(0.996))) / grade).b * halo;
vec3 gc = cor + (vec3(1.0) - cor) * 0.35;
pre = mix(pre, gc * a, h * 0.25);
float ah = h * (1.0 - a);
pre += gc * ah;
a += ah;
}
COLOR = vec4(a > 0.0 ? pre / a : vec3(0.0), a * tinta.a * COLOR.a);
}
In Cel und Pixel wird das Licht vor der Rampe zu 4 Tönen und die Tinte zu 0 oder 1. In Pixel fällt die Abtastung in die Mitte jeder Rasterzelle.
- Tempo. Im Spiel wirkt ein Schlag meist zwischen 24 und 30 Frames pro Sekunde am besten. In der Vorschau der Seite kannst du es vor dem Download testen.
- Größe. 256 px pro Frame lassen sich etwa auf das Doppelte vergrößern, ohne den Strich zu verlieren. Für Pixel-Art nimm den Pixel-Stil und den Filter
Nearest. - Farbe pro Element. Ein Spritesheet reicht für Feuer, Eis und Gift: Leg die Farben deines Spiels in einer Liste ab und wechsle sie im Moment des Treffers.
- Kosten. Jeder Effekt ist ein Spritesheet und ein Material: ein einziger Draw Call, leicht sogar auf dem Handy.
Noch Fragen? Die Effekte entstehen im Generator, und die Preise stehen auf der Preisseite.