Guide
How to use
From the generator to the game in a few minutes. Effects from the neural engine come colored and with transparency; effects from the basic engine come in 2 channels, with the color in the shader.
- Godot 4
- The 2-channel sheet, the
.tscnscene with the AnimatedSprite2D ready, the color shader and a short script that plays the effect the right way. - Colored sheet
- PNG with the 16 frames in a 4 × 4 grid, already in the color and style you picked. Works in any engine.
- 2-channel sheet
- The original sheet: light in red, ink in green. With it the color changes inside the game. It comes with the ramp explained.
- Aseprite and JSON
- Colored sheet with the JSON of frames and tags, in the format Phaser, GameMaker, Defold and Aseprite itself read.
- Separate frames
- 16 separate PNGs, for those who build the animation by hand.
- GIF
- To show the effect in a post, a devlog or on Discord.
- Neural engine
- Effects from the neural engine already come colored and with transparency: 32 frames in an 8 × 4 grid, at 28 frames per second. In Godot, the scene plays the sheet as it is, without the color shader; to lighten or darken it, use
modulate.
- Drag the effect folder into the project, for example
res://effects/seal/. - Instance the scene
selo.tscnwhere the effect happens. It plays on its own. - Change the color whenever you want, even mid-game:
# creates the effect where the hit lands and paints it red
var efeito = preload("res://efeitos/corte/corte.tscn").instantiate()
efeito.position = alvo.global_position
efeito.material.set_shader_parameter("tinta", Color("#F0524F"))
add_child(efeito)How it plays is already settled by the type of the effect:
- One-shot plays once and the node frees itself at the end. To reuse it, turn off
sumir_no_fimin the inspector and callplay(). - Loop plays nonstop. To make it vanish, animate
modulate.adown to 0. - Enter and stay draws itself (animation
entra) and then stays lit, going back and forth (animationfica).
Each instance has its own material, so ten copies of the same scene can have ten colors. Import the sheet as it is (Lossless, the 2D default) and do not use VRAM compression on it: it smears the two channels.
In Unity, the colored sheet goes in as a regular sprite sheet: Sprite Mode Multiple, sliced by the sheet grid (8 × 4 on the neural engine). To tint or brighten the effect in game, use the SpriteRenderer color:
efeito.GetComponent<SpriteRenderer>().color = new Color32(240, 82, 79, 255);To play it, build the animation with the frames in order, at the effect speed (28 frames per second on the neural engine).
Phaser, GameMaker, Defold, LÖVE, RPG Maker, Construct: download the colored sheet with the Aseprite JSON. The tags already say how to play it (golpe, laco, or entra and fica as ping-pong). To change the color inside the game, use the 2-channel sheet and the ramp below in your engine’s shader.
It is the same math the browser and the Godot package use. Light and ink go from 0 to 1; tinta is the chosen color.
shader_type canvas_item;
// Haljoy Studio: a folha guarda a luz no vermelho e a tinta no verde.
// Esta rampa pinta as duas na cor escolhida; troque "tinta" a qualquer hora, ate no meio da partida.
uniform vec4 tinta : source_color = vec4(0.91, 0.76, 0.42, 1.0);
uniform int estilo : hint_range(0, 2) = 0; // 0 pintado, 1 cel, 2 pixel
uniform float pixels_por_quadro = 64.0; // so no estilo pixel
uniform vec2 grade = vec2(4.0, 4.0); // colunas e linhas da folha
uniform float halo : hint_range(0.0, 1.0) = 0.0; // o brilho: a luz forte vaza no ar em volta (0 desliga; o site usa 0.85). Le o canal azul da folha
uniform float fumaca : hint_range(0.0, 1.0) = 0.0; // a fumaca neutra: a luz baixa perde a cor, a cor cheia fica so no aceso (o site usa 0.6)
void fragment() {
vec2 uv = UV;
if (estilo == 2) {
vec2 n = grade * pixels_por_quadro;
uv = (floor(uv * n) + 0.5) / n;
}
vec2 t = texture(TEXTURE, uv).rg;
float luz = t.r;
float tin = t.g;
if (estilo > 0) {
luz = luz < 0.16 ? 0.0 : (luz < 0.5 ? 0.42 : (luz < 0.84 ? 0.78 : 1.0));
tin = step(0.42, tin);
}
vec3 cor = tinta.rgb;
vec3 borda = cor * 0.38;
vec3 corpo = mix(borda, cor, smoothstep(0.12, 0.55, luz));
vec3 col = mix(corpo, vec3(1.0, 0.985, 0.95), smoothstep(0.78, 0.95, luz));
if (fumaca > 0.0) {
col = mix(col, dot(col, vec3(1.0 / 3.0)) * vec3(1.06, 1.0, 0.9), fumaca * (1.0 - clamp((luz - 0.62) / 0.14, 0.0, 1.0)));
}
float aL = clamp(luz * 1.6, 0.0, 1.0);
float aT = smoothstep(0.05, 0.4, tin);
vec3 tc = vec3(0.035, 0.04, 0.06) + cor * 0.035;
float a = aL + aT * (1.0 - aL);
vec3 pre = col * aL + tc * aT * (1.0 - aL);
if (halo > 0.0) {
// o brilho vem pronto no canal azul da folha (dois desfoques, feitos na exportacao): 1 leitura por pixel, sem pontilhado
vec2 cel = floor(uv * grade);
vec2 local = fract(uv * grade);
float h = texture(TEXTURE, (cel + clamp(local, vec2(0.004), vec2(0.996))) / grade).b * halo;
vec3 gc = cor + (vec3(1.0) - cor) * 0.35;
pre = mix(pre, gc * a, h * 0.25);
float ah = h * (1.0 - a);
pre += gc * ah;
a += ah;
}
COLOR = vec4(a > 0.0 ? pre / a : vec3(0.0), a * tinta.a * COLOR.a);
}
In cel and pixel, the light becomes 4 tones and the ink becomes 0 or 1 before the ramp. In pixel, the sample lands at the center of each grid cell.
- Speed. In a game, a strike usually looks best between 24 and 30 frames per second. The site preview lets you test it before you download.
- Size. 256 px per frame holds up when scaled to about 2 times without losing the stroke. For pixel art, use the pixel style and the
Nearestfilter. - Color per element. One sheet works for fire, ice and poison: keep your game’s colors in a list and swap them at the moment of the hit.
- Cost. Each effect is one sheet and one material: a single draw call, light even on phones.
Still have a question? Effects are made in the generator, and the prices are on the pricing page.