跳到正文
登录免费开始

教程

使用教程

从生成器到游戏,只要几分钟。神经引擎生成的特效自带颜色和透明通道;基础引擎生成的特效是双通道,颜色由着色器加入。

Godot 4
双通道序列帧图、已配好 AnimatedSprite2D 的 .tscn 场景、颜色着色器,以及一段能正确播放特效的简短脚本。
彩色序列帧图
16 帧排成 4 × 4 网格的 PNG,已是你选的颜色和风格。任何引擎都能用。
双通道序列帧图
原始图:红色通道存光,绿色通道存墨。有了它,颜色可以在游戏里更换。附带色带说明。
Aseprite 和 JSON
彩色序列帧图配上帧与标签的 JSON,格式可被 Phaser、GameMaker、Defold 和 Aseprite 本身读取。
单帧图片
16 张独立的 PNG,适合手动搭建动画的人。
GIF
用于在帖子、开发日志或 Discord 上展示特效。
神经引擎
神经引擎生成的特效自带颜色和透明通道:32 帧排成 8 × 4 的网格,每秒 28 帧。在 Godot 里,场景直接播放这张图,不使用颜色着色器;想调亮或调暗,请用 modulate。

  1. 把特效文件夹拖进项目,例如 res://effects/seal/。
  2. 在特效发生的位置实例化场景 selo.tscn。它会自动播放。
  3. 随时可以更换颜色,游戏运行中也可以:
GDScript
# 在命中的位置创建特效,并把它涂成红色
var efeito = preload("res://efeitos/corte/corte.tscn").instantiate()
efeito.position = alvo.global_position
efeito.material.set_shader_parameter("tinta", Color("#F0524F"))
add_child(efeito)

播放方式已经由特效的类型决定:

  • 单次只播放一次,结束后节点会自行释放。想重复使用的话,在属性面板里关掉 sumir_no_fim,然后调用 play()。
  • 循环会不停播放。想让它消失,把 modulate.a 动画过渡到 0。
  • 出现并停留会先把自己画出来(动画 entra),然后保持显示并来回播放(动画 fica)。

每个实例都有自己的材质,所以同一个场景的十个副本可以是十种颜色。请按原样导入序列帧图(Lossless,2D 的默认设置),不要对它使用 VRAM 压缩:那会把两个通道糊在一起。

在 Unity 中,彩色序列帧图按普通精灵图导入:Sprite Mode 选 Multiple,按序列帧图的网格切分(神经引擎为 8 × 4)。要在游戏里给特效染色或提亮,用 SpriteRenderer 的颜色:

C#
efeito.GetComponent<SpriteRenderer>().color = new Color32(240, 82, 79, 255);

播放时,把各帧按顺序做成动画,速度与特效一致(神经引擎为每秒 28 帧)。

Phaser、GameMaker、Defold、LÖVE、RPG Maker、Construct:下载带 Aseprite JSON 的彩色序列帧图。标签已经说明了播放方式(golpe、laco,或者以乒乓方式播放的 entra 和 fica)。想在游戏里换颜色,请在你引擎的着色器里使用双通道序列帧图和下面的色带。

浏览器和 Godot 资源包用的是同一套算法。光和墨的取值都是 0 到 1;tinta 是所选的颜色。

tinta_haljoy.gdshader (Godot 4)
shader_type canvas_item;
// Haljoy Studio: a folha guarda a luz no vermelho e a tinta no verde.
// Esta rampa pinta as duas na cor escolhida; troque "tinta" a qualquer hora, ate no meio da partida.

uniform vec4 tinta : source_color = vec4(0.91, 0.76, 0.42, 1.0);
uniform int estilo : hint_range(0, 2) = 0; // 0 pintado, 1 cel, 2 pixel
uniform float pixels_por_quadro = 64.0; // so no estilo pixel
uniform vec2 grade = vec2(4.0, 4.0); // colunas e linhas da folha
uniform float halo : hint_range(0.0, 1.0) = 0.0; // o brilho: a luz forte vaza no ar em volta (0 desliga; o site usa 0.85). Le o canal azul da folha
uniform float fumaca : hint_range(0.0, 1.0) = 0.0; // a fumaca neutra: a luz baixa perde a cor, a cor cheia fica so no aceso (o site usa 0.6)

void fragment() {
	vec2 uv = UV;
	if (estilo == 2) {
		vec2 n = grade * pixels_por_quadro;
		uv = (floor(uv * n) + 0.5) / n;
	}
	vec2 t = texture(TEXTURE, uv).rg;
	float luz = t.r;
	float tin = t.g;
	if (estilo > 0) {
		luz = luz < 0.16 ? 0.0 : (luz < 0.5 ? 0.42 : (luz < 0.84 ? 0.78 : 1.0));
		tin = step(0.42, tin);
	}
	vec3 cor = tinta.rgb;
	vec3 borda = cor * 0.38;
	vec3 corpo = mix(borda, cor, smoothstep(0.12, 0.55, luz));
	vec3 col = mix(corpo, vec3(1.0, 0.985, 0.95), smoothstep(0.78, 0.95, luz));
	if (fumaca > 0.0) {
		col = mix(col, dot(col, vec3(1.0 / 3.0)) * vec3(1.06, 1.0, 0.9), fumaca * (1.0 - clamp((luz - 0.62) / 0.14, 0.0, 1.0)));
	}
	float aL = clamp(luz * 1.6, 0.0, 1.0);
	float aT = smoothstep(0.05, 0.4, tin);
	vec3 tc = vec3(0.035, 0.04, 0.06) + cor * 0.035;
	float a = aL + aT * (1.0 - aL);
	vec3 pre = col * aL + tc * aT * (1.0 - aL);
	if (halo > 0.0) {
		// o brilho vem pronto no canal azul da folha (dois desfoques, feitos na exportacao): 1 leitura por pixel, sem pontilhado
		vec2 cel = floor(uv * grade);
		vec2 local = fract(uv * grade);
		float h = texture(TEXTURE, (cel + clamp(local, vec2(0.004), vec2(0.996))) / grade).b * halo;
		vec3 gc = cor + (vec3(1.0) - cor) * 0.35;
		pre = mix(pre, gc * a, h * 0.25);
		float ah = h * (1.0 - a);
		pre += gc * ah;
		a += ah;
	}
	COLOR = vec4(a > 0.0 ? pre / a : vec3(0.0), a * tinta.a * COLOR.a);
}

在赛璐珞和像素风格里,进入色带之前,光会变成 4 个色阶,墨会变成 0 或 1。在像素风格里,采样点落在每个网格单元的中心。

  • 速度。在游戏里,打击类特效通常在每秒 24 到 30 帧之间效果最好。可以先在网站的预览里试一试再下载。
  • 尺寸。每帧 256 px,放大到约 2 倍仍能保持笔触。做像素风时,请使用像素风格和 Nearest 过滤。
  • 按元素配色。同一张图可以用作火、冰和毒:把游戏里的颜色存成一个列表,在命中的瞬间切换。
  • 开销。每个特效只有一张图和一个材质:只需一次绘制调用,在手机上也很轻。

还有疑问?特效在生成器里创建,价格见价格页面。