Saltar al contenido
Iniciar sesiónCrear gratis

Guía

Cómo usar

Del generador al juego en pocos minutos. Los efectos del motor neuronal llegan con color y transparencia; los del motor básico llegan en 2 canales, con el color en el shader.

Godot 4
La hoja de 2 canales, la escena .tscn con el AnimatedSprite2D listo, el shader de color y un script corto que reproduce el efecto como debe.
Hoja en color
PNG con los 16 cuadros en una cuadrícula 4 × 4, ya en el color y el estilo que elegiste. Sirve en cualquier motor.
Hoja de 2 canales
La hoja original: luz en el rojo, tinta en el verde. Con ella el color cambia dentro del juego. Viene con la rampa explicada.
Aseprite y JSON
Hoja en color con el JSON de cuadros y etiquetas, en el formato que leen Phaser, GameMaker, Defold y el propio Aseprite.
Cuadros sueltos
16 PNG separados, para quien arma la animación a mano.
GIF
Para mostrar el efecto en un post, un devlog o Discord.
Motor neuronal
Los efectos del motor neuronal ya vienen en color y con transparencia: 32 cuadros en una cuadrícula 8 × 4, a 28 cuadros por segundo. En Godot, la escena reproduce la hoja tal cual, sin el shader de color; para aclarar u oscurecer, usa modulate.

  1. Arrastra la carpeta del efecto dentro del proyecto, por ejemplo res://efectos/sello/.
  2. Instancia la escena selo.tscn donde ocurre el efecto. Se reproduce sola.
  3. Cambia el color cuando quieras, incluso en mitad de la partida:
GDScript
# crea el efecto en el lugar del golpe y lo pinta de rojo
var efeito = preload("res://efeitos/corte/corte.tscn").instantiate()
efeito.position = alvo.global_position
efeito.material.set_shader_parameter("tinta", Color("#F0524F"))
add_child(efeito)

La forma de reproducirse ya viene resuelta por el tipo de efecto:

  • Golpe se reproduce una vez y el nodo se borra solo al final. Para reutilizarlo, desactiva sumir_no_fim en el inspector y llama a play().
  • Bucle se repite sin parar. Para que desaparezca, anima modulate.a hasta 0.
  • Entra y queda se dibuja (animación entra) y después queda encendido, yendo y volviendo (animación fica).

Cada instancia tiene su propio material, así que diez copias de la misma escena pueden tener diez colores. Importa la hoja tal cual (Lossless, el valor por defecto del 2D) y no uses compresión de VRAM en ella: emborrona los dos canales.

En Unity, la hoja en color entra como una hoja de sprites normal: Sprite Mode Multiple, cortada por la cuadrícula de la hoja (8 × 4 en el motor neuronal). Para teñir o aclarar el efecto en el juego, usa el color del SpriteRenderer:

C#
efeito.GetComponent<SpriteRenderer>().color = new Color32(240, 82, 79, 255);

Para reproducirlo, arma la animación con los cuadros en orden, a la velocidad del efecto (28 cuadros por segundo en el motor neuronal).

Phaser, GameMaker, Defold, LÖVE, RPG Maker, Construct: descarga la hoja en color con el JSON de Aseprite. Las etiquetas ya dicen cómo reproducirla (golpe, laco, o entra y fica en ida y vuelta). Para cambiar el color dentro del juego, usa la hoja de 2 canales y la rampa de abajo en el shader de tu motor.

Es la misma cuenta del navegador y del paquete de Godot. Luz y tinta van de 0 a 1; tinta es el color elegido.

tinta_haljoy.gdshader (Godot 4)
shader_type canvas_item;
// Haljoy Studio: a folha guarda a luz no vermelho e a tinta no verde.
// Esta rampa pinta as duas na cor escolhida; troque "tinta" a qualquer hora, ate no meio da partida.

uniform vec4 tinta : source_color = vec4(0.91, 0.76, 0.42, 1.0);
uniform int estilo : hint_range(0, 2) = 0; // 0 pintado, 1 cel, 2 pixel
uniform float pixels_por_quadro = 64.0; // so no estilo pixel
uniform vec2 grade = vec2(4.0, 4.0); // colunas e linhas da folha
uniform float halo : hint_range(0.0, 1.0) = 0.0; // o brilho: a luz forte vaza no ar em volta (0 desliga; o site usa 0.85). Le o canal azul da folha
uniform float fumaca : hint_range(0.0, 1.0) = 0.0; // a fumaca neutra: a luz baixa perde a cor, a cor cheia fica so no aceso (o site usa 0.6)

void fragment() {
	vec2 uv = UV;
	if (estilo == 2) {
		vec2 n = grade * pixels_por_quadro;
		uv = (floor(uv * n) + 0.5) / n;
	}
	vec2 t = texture(TEXTURE, uv).rg;
	float luz = t.r;
	float tin = t.g;
	if (estilo > 0) {
		luz = luz < 0.16 ? 0.0 : (luz < 0.5 ? 0.42 : (luz < 0.84 ? 0.78 : 1.0));
		tin = step(0.42, tin);
	}
	vec3 cor = tinta.rgb;
	vec3 borda = cor * 0.38;
	vec3 corpo = mix(borda, cor, smoothstep(0.12, 0.55, luz));
	vec3 col = mix(corpo, vec3(1.0, 0.985, 0.95), smoothstep(0.78, 0.95, luz));
	if (fumaca > 0.0) {
		col = mix(col, dot(col, vec3(1.0 / 3.0)) * vec3(1.06, 1.0, 0.9), fumaca * (1.0 - clamp((luz - 0.62) / 0.14, 0.0, 1.0)));
	}
	float aL = clamp(luz * 1.6, 0.0, 1.0);
	float aT = smoothstep(0.05, 0.4, tin);
	vec3 tc = vec3(0.035, 0.04, 0.06) + cor * 0.035;
	float a = aL + aT * (1.0 - aL);
	vec3 pre = col * aL + tc * aT * (1.0 - aL);
	if (halo > 0.0) {
		// o brilho vem pronto no canal azul da folha (dois desfoques, feitos na exportacao): 1 leitura por pixel, sem pontilhado
		vec2 cel = floor(uv * grade);
		vec2 local = fract(uv * grade);
		float h = texture(TEXTURE, (cel + clamp(local, vec2(0.004), vec2(0.996))) / grade).b * halo;
		vec3 gc = cor + (vec3(1.0) - cor) * 0.35;
		pre = mix(pre, gc * a, h * 0.25);
		float ah = h * (1.0 - a);
		pre += gc * ah;
		a += ah;
	}
	COLOR = vec4(a > 0.0 ? pre / a : vec3(0.0), a * tinta.a * COLOR.a);
}

En cel y en píxel, la luz pasa a 4 tonos y la tinta pasa a 0 o 1 antes de la rampa. En píxel, la muestra cae en el centro de cada celda de la cuadrícula.

  • Velocidad. En el juego, un golpe suele quedar mejor entre 24 y 30 cuadros por segundo. La vista previa del sitio te deja probarlo antes de descargar.
  • Tamaño. 256 px por cuadro aguanta ampliarse hasta unas 2 veces sin perder el trazo. Para pixel art, usa el estilo píxel y el filtro Nearest.
  • Color por elemento. Una hoja sirve para fuego, hielo y veneno: guarda los colores de tu juego en una lista y cámbialos en el momento del golpe.
  • Coste. Cada efecto es una hoja y un material: una llamada de dibujo, ligera incluso en móviles.

¿Te quedó alguna duda? Los efectos se crean en el generador, y los precios están en la página de precios.