Guide
Mode d’emploi
Du générateur au jeu en quelques minutes. Les effets du moteur neuronal arrivent en couleur, avec transparence ; ceux du moteur de base arrivent en 2 canaux, avec la couleur dans le shader.
- Godot 4
- La planche à 2 canaux, la scène
.tscnavec l’AnimatedSprite2D prêt, le shader de couleur et un court script qui joue l’effet comme il faut. - Planche en couleur
- PNG avec les 16 images dans une grille 4 × 4, déjà dans la couleur et le style choisis. Convient à tous les moteurs.
- Planche à 2 canaux
- La planche d’origine : lumière dans le rouge, encre dans le vert. Avec elle, la couleur change dans le jeu. Elle est livrée avec la rampe expliquée.
- Aseprite et JSON
- Planche en couleur avec le JSON des images et des tags, au format que lisent Phaser, GameMaker, Defold et Aseprite lui-même.
- Images séparées
- 16 PNG séparés, pour ceux qui montent l’animation à la main.
- GIF
- Pour montrer l’effet dans un post, un devlog ou sur Discord.
- Moteur neuronal
- Les effets du moteur neuronal arrivent déjà en couleur et avec transparence : 32 images dans une grille 8 × 4, à 28 images par seconde. Dans Godot, la scène joue la planche telle quelle, sans le shader de couleur ; pour éclaircir ou assombrir, utilisez
modulate.
- Glissez le dossier de l’effet dans le projet, par exemple
res://effets/sceau/. - Instanciez la scène
selo.tscnlà où l’effet a lieu. Elle se joue toute seule. - Changez la couleur quand vous voulez, même en pleine partie :
# crée l’effet à l’endroit du coup et le peint en rouge
var efeito = preload("res://efeitos/corte/corte.tscn").instantiate()
efeito.position = alvo.global_position
efeito.material.set_shader_parameter("tinta", Color("#F0524F"))
add_child(efeito)La façon de jouer est déjà réglée par le type de l’effet :
- Coup unique se joue une fois et le nœud se supprime tout seul à la fin. Pour le réutiliser, désactivez
sumir_no_fimdans l’inspecteur et appelezplay(). - Boucle tourne sans arrêt. Pour la faire disparaître, animez
modulate.ajusqu’à 0. - Entre et reste se dessine (animation
entra) puis reste allumé, en va-et-vient (animationfica).
Chaque instance a son propre matériau : dix copies de la même scène peuvent donc avoir dix couleurs. Importez la planche telle quelle (Lossless, le réglage 2D par défaut) et n’utilisez pas de compression VRAM dessus : elle brouille les deux canaux.
Dans Unity, la planche en couleur s’importe comme une planche de sprites ordinaire : Sprite Mode Multiple, découpée selon la grille de la planche (8 × 4 sur le moteur neuronal). Pour teinter ou éclaircir l’effet en jeu, utilisez la couleur du SpriteRenderer :
efeito.GetComponent<SpriteRenderer>().color = new Color32(240, 82, 79, 255);Pour la jouer, créez l’animation avec les images dans l’ordre, à la vitesse de l’effet (28 images par seconde sur le moteur neuronal).
Phaser, GameMaker, Defold, LÖVE, RPG Maker, Construct : téléchargez la planche en couleur avec le JSON d’Aseprite. Les tags disent déjà comment la jouer (golpe, laco, ou entra et fica en va-et-vient). Pour changer la couleur dans le jeu, utilisez la planche à 2 canaux et la rampe ci-dessous dans le shader de votre moteur.
C’est le même calcul que dans le navigateur et le paquet Godot. Lumière et encre vont de 0 à 1 ; tinta est la couleur choisie.
shader_type canvas_item;
// Haljoy Studio: a folha guarda a luz no vermelho e a tinta no verde.
// Esta rampa pinta as duas na cor escolhida; troque "tinta" a qualquer hora, ate no meio da partida.
uniform vec4 tinta : source_color = vec4(0.91, 0.76, 0.42, 1.0);
uniform int estilo : hint_range(0, 2) = 0; // 0 pintado, 1 cel, 2 pixel
uniform float pixels_por_quadro = 64.0; // so no estilo pixel
uniform vec2 grade = vec2(4.0, 4.0); // colunas e linhas da folha
uniform float halo : hint_range(0.0, 1.0) = 0.0; // o brilho: a luz forte vaza no ar em volta (0 desliga; o site usa 0.85). Le o canal azul da folha
uniform float fumaca : hint_range(0.0, 1.0) = 0.0; // a fumaca neutra: a luz baixa perde a cor, a cor cheia fica so no aceso (o site usa 0.6)
void fragment() {
vec2 uv = UV;
if (estilo == 2) {
vec2 n = grade * pixels_por_quadro;
uv = (floor(uv * n) + 0.5) / n;
}
vec2 t = texture(TEXTURE, uv).rg;
float luz = t.r;
float tin = t.g;
if (estilo > 0) {
luz = luz < 0.16 ? 0.0 : (luz < 0.5 ? 0.42 : (luz < 0.84 ? 0.78 : 1.0));
tin = step(0.42, tin);
}
vec3 cor = tinta.rgb;
vec3 borda = cor * 0.38;
vec3 corpo = mix(borda, cor, smoothstep(0.12, 0.55, luz));
vec3 col = mix(corpo, vec3(1.0, 0.985, 0.95), smoothstep(0.78, 0.95, luz));
if (fumaca > 0.0) {
col = mix(col, dot(col, vec3(1.0 / 3.0)) * vec3(1.06, 1.0, 0.9), fumaca * (1.0 - clamp((luz - 0.62) / 0.14, 0.0, 1.0)));
}
float aL = clamp(luz * 1.6, 0.0, 1.0);
float aT = smoothstep(0.05, 0.4, tin);
vec3 tc = vec3(0.035, 0.04, 0.06) + cor * 0.035;
float a = aL + aT * (1.0 - aL);
vec3 pre = col * aL + tc * aT * (1.0 - aL);
if (halo > 0.0) {
// o brilho vem pronto no canal azul da folha (dois desfoques, feitos na exportacao): 1 leitura por pixel, sem pontilhado
vec2 cel = floor(uv * grade);
vec2 local = fract(uv * grade);
float h = texture(TEXTURE, (cel + clamp(local, vec2(0.004), vec2(0.996))) / grade).b * halo;
vec3 gc = cor + (vec3(1.0) - cor) * 0.35;
pre = mix(pre, gc * a, h * 0.25);
float ah = h * (1.0 - a);
pre += gc * ah;
a += ah;
}
COLOR = vec4(a > 0.0 ? pre / a : vec3(0.0), a * tinta.a * COLOR.a);
}
En cel et en pixel, la lumière passe à 4 tons et l’encre à 0 ou 1 avant la rampe. En pixel, l’échantillon tombe au centre de chaque cellule de la grille.
- Vitesse. En jeu, un coup rend souvent mieux entre 24 et 30 images par seconde. L’aperçu du site vous permet de tester avant de télécharger.
- Taille. 256 px par image supporte un agrandissement d’environ 2 fois sans perdre le trait. Pour le pixel art, utilisez le style pixel et le filtre
Nearest. - Couleur par élément. Une planche sert pour le feu, la glace et le poison : gardez les couleurs de votre jeu dans une liste et changez-les au moment du coup.
- Coût. Chaque effet est une planche et un matériau : un seul appel de dessin, léger même sur mobile.
Encore une question ? Les effets se créent dans le générateur, et les prix sont sur la page des tarifs.